global static xPNA.GlobalPlanService.PlanBlankCreateResponseCollection createBlankPlans(xPNA.GlobalPlanService.PlanBlankCreateRequestCollection request)

Creates a blank plan.

Input Parameters

Return Value

The PlanBlankCreateResponse of the newly created plan.

Sample Code

//Note: This sample code is for demonstration purposes only. It is not intended for
//use in a production environment, is not guaranteed against defects or errors, and
//is in no way optimized or streamlined.


//Create an instance of PlanBlankCreateRequest.
xpna.GlobalPlanService.PlanBlankCreateRequest request = new xpna.GlobalPlanService.PlanBlankCreateRequest();
request.planName = 'Blank Plan Example Name';
request.currentScenarioName = 'Initial';
request.description = 'Description';

//Get dimensions that are used to create the plan as rows.
List<xpna__Dimension__c> dimensionRowsList = [SELECT Id FROM xpna__Dimension__c WHERE Name LIKE 'DimensionRows%' ORDER BY Name];
request.dimensionRowIds = new List<Id>(new Map<Id, xpna__Dimension__c>(dimensionRowsList).keySet());

//Get dimensions that are used to create the plan as columns.
List<xpna__Dimension__c> dimensionColumnsList = [SELECT Id FROM xpna__Dimension__c WHERE Name LIKE 'DimensionColumns%' ORDER BY Name];
request.dimensionColumnIds = new List<Id>(new Map<Id, xpna__Dimension__c>(dimensionColumnsList).keySet());

//Get the measures that are used to create the plan.
List<xpna__Measure__c> measureList = [SELECT Id FROM xpna__Measure__c WHERE Name Like 'Measure%'];
request.measureIds = new List<Id>(new Map<Id, xpna__Measure__c>(measureList).keySet());

//Optional, by default it is true if you do not provide it.
request.measureAsColumns = true;

//Create an instance of the object request.
xpna.GlobalPlanService.PlanBlankCreateRequestCollection requestCollection = new xpna.GlobalPlanService.PlanBlankCreateRequestCollection();
//Add a new PlanBlankCreateRequest to the request list.
requestCollection.planBlankCreateRequests.add(request);

//Call the API method.
xpna.GlobalPlanService.PlanBlankCreateResponseCollection result = xpna.GlobalPlanService.createBlankPlans(requestCollection);

global static xPNA.GlobalPlanService.PlanFromAnalyticsCreateResponseCollection createPlansFromAnalytics(xPNA.GlobalPlanService.PlanFromAnalyticsCreateRequestCollection request)

Creates a plan from Analytics data source.

Input Parameters

Return Value

The PlanFromAnalyticsCreateResponse of the newly created plan.

Sample Code

//Note: This sample code is for demonstration purposes only. It is not intended for
//use in a production environment, is not guaranteed against defects or errors, and
//is in no way optimized or streamlined.


//Create an instance of PlanFromAnalyticsCreateRequest.
xpna.GlobalPlanService.PlanFromAnalyticsCreateRequest request = new xpna.GlobalPlanService.PlanFromAnalyticsCreateRequest();
request.planName = 'Plan From Analytics Example Name';
request.currentScenarioName = 'Initial';
request.description = 'Description';

//Get the Data Source that is used to create the plan.
List<xpna__DataSource__c> dataSourceList = [SELECT Id, xpna__DatasetApiName__c FROM xpna__DataSource__c WHERE Name = 'Data Source'];
Id dataSourceId = dataSourceList[0].Id;
request.dataSourceId = dataSourceId;

//Get dimensions that are used to create the plan as rows.
List<xpna__Dimension__c> dimensionRowsList = [SELECT Id FROM xpna__Dimension__c WHERE Name LIKE 'DimensionRows%' ORDER BY Name];
request.dimensionRowIds = new List<Id>(new Map<Id, xpna__Dimension__c>(dimensionRowsList).keySet());

//Get dimensions that are used to create the plan as columns.
List<xpna__Dimension__c> dimensionColumnsList = [SELECT Id FROM xpna__Dimension__c WHERE Name LIKE 'DimensionColumns%' ORDER BY Name];
request.dimensionColumnIds = new List<Id>(new Map<Id, xpna__Dimension__c>(dimensionColumnsList).keySet());

//Get the measures that are used to create the plan.
List<xpna__Measure__c> measureList = [SELECT Id FROM xpna__Measure__c WHERE Name LIKE 'Measure%'];
request.measureIds = new List<Id>(new Map<Id, xpna__Measure__c>(measureList).keySet());

//Optional, by default it is true if you do not provide it.
request.measureAsColumns = true;

//Optional, set a dimension value map.
Id dimensionMapped = dimensionColumnsList[0].Id;
Map<String, String> valueMappings = new Map<String, String>();
valueMappings.put('Australia', 'Spain');
valueMappings.put('United Kingdom', 'Spain');

Map<Id, Map<String, String>> dimensionValueMappings = new Map<Id, Map<String, String>>();
dimensionValueMappings.put(dimensionMapped, valueMappings);

xpna.GlobalPlanService.DimensionValueMappingCollection dimensionValueMappingCollection = new xpna.GlobalPlanService.DimensionValueMappingCollection(); 
dimensionValueMappingCollection.dimensionValueMappings = dimensionValueMappings;
request.valueMappings = dimensionValueMappingCollection;

//Optional, filters for the dimension value.
xpna.GlobalPlanService.ListFilterCollection filterCollection = new xpna.GlobalPlanService.ListFilterCollection();
List<xpna.GlobalPlanService.DimensionFilter> dimensionFilters = new List<xpna.GlobalPlanService.DimensionFilter>();

xpna.GlobalPlanService.DimensionFilter filter = new xpna.GlobalPlanService.DimensionFilter();
filter.dimensionId = dimensionRowsList[0].Id;
filter.comparisonOperator = xpna.GlobalPlanService.FilterComparisonOperator.EQUAL;
// values are different in every dataset, use yours
filter.values = new List<String>{'Adelaide', 'Birmingham'};

dimensionFilters.add(filter);
filterCollection.filters = dimensionFilters;
request.filters = filterCollection;

//Create an instance of the object request.
xpna.GlobalPlanService.PlanFromAnalyticsCreateRequestCollection requestCollection = new xpna.GlobalPlanService.PlanFromAnalyticsCreateRequestCollection();
//Add a new PlanFromAnalyticsCreateRequest to the request list.
requestCollection.planFromAnalyticsCreateRequests.add(request);

//Call the API method.
xpna.GlobalPlanService.PlanFromAnalyticsCreateResponseCollection result = xpna.GlobalPlanService.createPlansFromAnalytics(requestCollection);

global static xPNA.GlobalPlanService.PlanDeleteResponseCollection deletePlans(xPNA.GlobalPlanService.PlanDeleteRequestCollection request)

Deletes the plans.

Input Parameters

Return Value

A list of PlanResponse.

Sample Code

//Note: This sample code is for demonstration purposes only. It is not intended for
//use in a production environment, is not guaranteed against defects or errors, and
//is in no way optimized or streamlined.


//Create an instance of the object request.
xpna.GlobalPlanService.PlanDeleteRequestCollection request = new xpna.GlobalPlanService.PlanDeleteRequestCollection();

//Create an instance of PlanDeleteRequest and set the ID of the plan to be deleted.
xpna.GlobalPlanService.PlanDeleteRequest planToDeleteRequest = new xpna.GlobalPlanService.PlanDeleteRequest();
planToDeleteRequest.planId = Id.valueOf('a0D7X0000050TrEUAU');

//Add a new PlanDeleteRequest to the request list.
request.planDeleteRequests.add(planToDeleteRequest);

//Call the API method.
xpna.GlobalPlanService.PlanDeleteResponseCollection result = xpna.GlobalPlanService.deletePlans(request);

global DimensionFilter()

Creates a new empty DimensionFilter.

global DimensionValueMappingCollection()

Creates a new empty DimensionValueMappingCollection.

global ListFilterCollection()

Creates a new empty ListFilterCollection.

global PlanBlankCreateRequest()

Creates a new empty PlanBlankCreateRequest.

global PlanBlankCreateRequestCollection()

Creates a new empty PlanBlankCreateRequestCollection.

global PlanBlankCreateResponse()

Creates a new empty PlanBlankCreateResponse.

global PlanBlankCreateResponseCollection()

Creates a new empty PlanBlankCreateResponseCollection.

global PlanCreateRequest()

Creates a new empty PlanCreateRequest.

global PlanDeleteRequest()

Default empty constructor to represent the class.

global PlanDeleteRequestCollection()

Default empty constructor to represent the class outside the namespace.

global PlanDeleteResponse()

Default empty constructor to represent the class outside the namespace.

global PlanDeleteResponseCollection()

Default empty constructor to represent the class outside the namespace.

global PlanFromAnalyticsCreateRequest()

Creates a new empty PlanFromAnalyticsCreateRequest.

global PlanFromAnalyticsCreateRequestCollection()

Creates a new empty PlanFromAnalyticsCreateRequestCollection.

global PlanFromAnalyticsCreateResponse()

Creates a new empty PlanFromAnalyticsCreateResponse.

global PlanFromAnalyticsCreateResponseCollection()

Creates a new empty PlanFromAnalyticsCreateResponseCollection.