global with sharing class AddToProjectFromEstimatePlugin

A class that contains plugins to use after the Add to Existing Project action has been completed.

global interface IAddToProjectFromEstimatePlugin

Provides an interface that can be used to create plugins to be executed after the Add to Existing Project action is complete. This enables the custom Apex classes to be executed. To set up a plugin, create a fferpcore__Plugin__mdt record with a fferpcore__ExtensionPoint__c of AddToProjectFromEstimatePlugin.IAddToProjectFromEstimatePlugin, and a ClassName that matches an Apex class which implements that interface.

Sample Code

//Note: This sample code is for demonstration purposes only. It is not intended for
//use in a production environment, is not guaranteed against defects or errors, and
//is in no way optimized or streamlined.

/**
 * This Add to Project From Estimate plugin uses the Add_From_Estimate_Timestamp__c custom date/time field on the Project object.
 * It indicates the most recent time that records were added to a project from an estimate.
 */
global with sharing class AddToProjectTimestampPlugin implements ffscpq.AddToProjectFromEstimatePlugin.IAddToProjectFromEstimatePlugin {
    global ffscpq.AddToProjectFromEstimatePlugin.Response executePlugin(
        ffscpq.AddToProjectFromEstimatePlugin.Request request
    ) {
        /**
         * The resulting data is retrieved from the estimate product instances used in the Add to Existing Project action which executed this plugin.
         * The IDs of the projects related to these estimate product instances are then stored in a set.
         */
        List<ffscpq.AddToProjectFromEstimatePlugin.Result> results = request.getResults();
        Set<Id> projectIds = new Set<Id>();

        for (ffscpq.AddToProjectFromEstimatePlugin.Result result : results) {
            // Only the data of successfully processed estimate product instances are used.
            if (result.getStatus() == ffscpq.EstimateActionStatus.SUCCESSFUL) {
                projectIds.add(result.getProjectId());
            }
        }

        // Select the Add_From_Estimate_Timestamp__c field on the projects. Retrieve the time and date from the org and add it to the Add_From_Estimate_Timestamp__c field.
        List<pse__Proj__c> projects = [
            SELECT Id, Add_From_Estimate_Timestamp__c
            FROM pse__Proj__c
            WHERE Id IN :projectIds
        ];

        for (pse__Proj__c project : projects) {
            project.Add_From_Estimate_Timestamp__c = Datetime.now();
        }

        update projects;

        // Create the response.
        return buildResponse(request);
    }

    private ffscpq.AddToProjectFromEstimatePlugin.Response buildResponse(
        ffscpq.AddToProjectFromEstimatePlugin.Request request
    ) {
        ffscpq.AddToProjectFromEstimatePlugin.Response response = new ffscpq.AddToProjectFromEstimatePlugin.Response();

        response.setRequest(request);

        return response;
    }
}

Methods

global with sharing class Request

The request structure for executing the plugin.

Methods

global with sharing class Result

Result containing data of the estimate product instance used in the Add to Existing Project action that executes this plugin.

Methods

global with sharing class Response

The response structure for executing the plugin.

Methods

global with sharing class Error

The structure of the errors that occurred during the Add to Existing Project action which executed this plugin.

Methods